Web Developer - Author(s): Rob Earl

Adding Stackoverflow user feed to your homepage

Rob Earl — Sun, 16 Dec 2012 16:48:00 +0000

Following on from a comment on a previous post, this post will demonstrate how to use XML::Feed and Template::Toolkit to format your recent Stackoverflow activity, suitable for including on your own web page. Aptly, this was aided by a stackoverflow question!

This time we can use XML::Feed both to get and parse the feed:

Code: perl

use XML::Feed;
my $feed = XML::Feed->parse(URI->new('http://stackoverflow.com/feeds/user/1691146'));

We need to adapt the template to account for XML::Feed's differences:

Code: perl

my $template = <<"TEMPLATE";
[% feed.title %]

Activity:
[% FOREACH item = feed.items %]
[% item.issued.dmy %] [% item.issued.hms %]\t[% item.title %]
[% END %]
TEMPLATE

And the template toolkit invocation:

Code: perl

$tt->process( \$template, { 'feed' => $feed } )
or die $tt->error();

Full example:

Code: perl

#!/usr/bin/perl

use strict;
use warnings;

use XML::Feed;
use Template;

my $stackoverflow_id = 1691146;
my $stackoverflow_url = "http://stackoverflow.com/feeds/user/$stackoverflow_id";

my $template = <<"TEMPLATE";
[% feed.title %]

Activity:
[% FOREACH item = feed.items %]
[% item.issued.dmy %] [% item.issued.hms %]\t[% item.title %]
[% END %]
TEMPLATE

my $tt = Template->new( 'STRICT' => 1 )
or die "Failed to load template: $Template::ERROR\n";

my $feed = XML::Feed->parse(URI->new($stackoverflow_url));

$tt->process( \$template, { 'feed' => $feed } )
or die $tt->error();

This is still a really simple script with added support for Atom feeds.

Original post blogged on LessThanDot.

Create HTML from output of Perl::Critic

Rob Earl — Sat, 22 Sep 2012 07:46:00 +0000

Perl::Critic is great. If you haven't tried it, you should. It can help you improve the quality of your code no end.

I wrote this script to make it easier to view the feedback in the context of the code itself. When run in a directory containing Perl code it'll create a critic_html directory containing index.html summarizing the results:

Clicking through to any of the files will give you all the violations found by Perl::Critic, inline with the code:

In addition to Perl::Critic, the script uses Template::Toolkit to format the output. The code below and templates can be found in the attached critic_html.zip

Code: perl

#!/usr/bin/perl

use strict;
use warnings;

use Perl::Critic;
use Perl::Critic::Utils;

use Template;
use Cwd qw(abs_path);
use File::Basename;
use English qw(-no_match_vars);

use constant SEVERITY => 1; # Include all violations.
use constant SKIP_GOOD => 0; # Skip files with no violations?

mkdir 'critic_html';
mkdir 'critic_html/src';

use autodie;

# Analyse all perl files below the current directory.
my @files = Perl::Critic::Utils::all_perl_files(q{.});

my @summary = (); # Store statistics on each file processed.

foreach my $file (@files) {
# Create a new Critic for per file statistics.
my $critic = Perl::Critic->new( '-severity' => SEVERITY );

my $file_safe = $file;
$file_safe =~ s/[\W]/_/g;

my @violations = $critic->critique($file);
next if (!@violations && SKIP_GOOD);

push @summary, { 'filename' => $file,
'link' => "src/$file_safe.html",
'stats' => $critic->statistics() };

open my $FH, '<', $file;
my @lines = <$FH>;
close $FH;

# Attach all violations to the line they were found on.
my @violations_by_line = ();
my $line_number = 1;
foreach my $line (@lines) {
# Get all the violations for the current line.
my @line_violations = grep { $_->line_number() == $line_number} @violations;
push @violations_by_line, { 'number' => $line_number,
'content' => $line,
'violations' => \@line_violations };
$line_number++;
}

write_html("critic_html/src/$file_safe.html", 'codefile', { 'title' => "Critic Analysis of $file",
'lines' => \@violations_by_line } );
}

write_html('critic_html/index.html', 'index', { 'title' => 'Perl::Critic::HTML Summary',
'files' => \@summary });

sub write_html {
my ($filename, $template, $data) = @_;

# Include templates from the install directory.
my $tt = Template->new({ 'INCLUDE_PATH' => dirname(abs_path($PROGRAM_NAME)).'/templates' } );
print "Writing $filename\n";
open my $FILE, '>', $filename;
$tt->process($template, $data, $FILE);
close $FILE;

return;
}

Original post blogged on LessThanDot.

Taming RSS Feeds with XML::RSS and Template::Toolkit

Rob Earl — Fri, 14 Sep 2012 11:01:00 +0000

This is a remarkably simple trick which I've found very handy. With a few lines of Perl you can take any RSS feed and format it to your liking.

Get the Feed

You can do this using LWP::Simple:

Code: perl

use LWP::Simple;

my $feed_url = 'http://feeds.bbci.co.uk/news/rss.xml';
my $feed = get($feed_url)
or die ("Failed to fetch feed.");

Process the Raw Result

Using XML::RSS, convert the raw feed into a more manageable hash.

Code: perl

use XML::RSS;

my $rss = XML::RSS->new();
$rss->parse($feed);

Format to Your Liking

Template::Toolkit can take in a template and a hash reference of values to substitute into the template.

Code: perl

# Define a template
my $template = <<"TEMPLATE";
[% channel.title %]

Headlines:
[% FOREACH item = items %]
[% item.pubDate %]\t[% item.title %]
[% END %]
TEMPLATE

This simple template will take the BBC news feed from above and print out a list of headlines with publication dates.

Code: perl

my $tt = Template->new()
or die ("Failed to load template: $Template::ERROR\n");

# Combine the template with the processed RSS feed.
$tt->process ( \$template, $rss )
or die $tt->error();

Putting it All Together

Code: perl

#!/usr/bin/perl
use strict;
use warnings;

use XML::RSS;
use LWP::Simple;
use Template;

##################
# Configuration:
#
##################
my $feed_url = 'http://feeds.bbci.co.uk/news/rss.xml';
my $template = <<"TEMPLATE";
[% channel.title %]

Headlines:
[% FOREACH item = items %]
[% item.pubDate %]\t[% item.title %]
[% END %]
TEMPLATE

##################
##################

my $tt = Template->new()
or die ("Failed to load template: $Template::ERROR\n");
my $feed = get($feed_url)
or die ('Failed to fetch feed.');
my $rss = XML::RSS->new();
$rss->parse($feed);

$tt->process ( \$template, $rss )
or die $tt->error();

Code: bash

rob@arrakis:~/public_html/rss-reader$ perl rss-reader.pl
BBC News - Home

Headlines:

Fri, 14 Sep 2012 12:15:22 GMT Kate privacy invasion 'grotesque'

Fri, 14 Sep 2012 11:49:10 GMT US missions on film protest alert

Fri, 14 Sep 2012 12:25:25 GMT Alps attack girl returning to UK

Fri, 14 Sep 2012 10:17:03 GMT Woman is held after car body find

In this example the RSS feed and template are defined in code but they can just as easily be defined in files or a database allowing for changes/additions without deploying new code.

Original post blogged on LessThanDot.

Using a Perl Singleton to Share Values Between Objects

Rob Earl — Wed, 12 Sep 2012 14:54:00 +0000

It's been quite a while since I last posted here. Since my last entry I got a new job, got married, went on honeymoon (got back yesterday!) and spent quite a lot of time maintaining legacy Perl code.

One thing I see a lot is sharing objects by passing them to the constructor of a new object. This is fine until you're dealing with complicated sets of objects within objects.

Code: perl

#!/usr/bin/perl

use strict;

# Read some variables out of a configuration file.
my $config = get_config($config_file);

# Create a new object which contains an object which uses some values from the config.
my $object = MyObject->new($config);
$object->do_something();

package MyObject;

sub new {
my $class = shift;
my $config = shift;

# Store the config incase we create any objects which need it.
my $self = { 'config' => $config };

return bless $self, $class;
}

sub do_something {
my $self = shift;

my $object2 = MyObject2->new($self->{'config'});

return $object2->do_something_else();
}

MyObject is now holding a reference to the config object which it doesn't need directly. This will only get worse if MyObject2 needs another object which requires the config object, etc.

Instead we could use a singleton object:

Code: perl

package MyConfigObject;

use strict;
use Carp;

my $config = undef;

sub new {

if(!$config) {
my $class = shift;
my $config_file = shift;

croak unless $config_file;

$config = bless {}, $class;
$config->parse_file($config_file);
}

return $config;
}

The example above changes to:

Code: perl

#!/usr/bin/perl

use strict;

# Create a new object to hold the values from our config file.
my $config = MyConfigObject->new($config_file);

# Create a new object which contains an object which uses some values from the config.
my $object = MyObject->new();
$object->do_something();

package MyObject;

sub new {
my $class = shift;

return bless {}, $class;
}

sub do_something {
my $self = shift;

my $object2 = MyObject2->new();

return $object2->do_something_else();
}

package MyObject2;

sub new {
# Get the config object
my $config = MyConfigObject->new();

# Do some stuff with it!
}

Whenever we need to use a value from the config file, we create a new MyConfigObject and get the instance we already created without having to reparse the config file or maintain complicated links through parent objects.

Original post blogged on LessThanDot.

Catching Key Conflicts with Perl's Class::DBI

Rob Earl — Mon, 31 Jan 2011 09:52:00 +0000

When inserting to a database I find it more convenient to catch a key conflict than to perform a select in order to check for duplicates. Defining a column as unique will ensure data integrity at the lowest level.

Code: sql

CREATE TABLE customer (
id int AUTO_INCREMENT,
name varchar(20),
address varchar(50),
email varchar(50),
constraint PRIMARY KEY(id),
UNIQUE(email)
);

Catching a user attempting to register with an email address which is already in the database is fairly simple when using DBI:

Code: perl

my $row = $dbh->do(qq{INSERT INTO customer ( name, address, email ) VALUES (?,?,?);}, undef, ("Rob", "Rob's House", "my\@email.com")); # Returns undef on error.
&error($dbh->errstr) unless $row; # Forward to error handler.

Class::DBI is a database abstraction Perl module. It wasn't immediately apparent to me how to handle a key conflict when using it. After a little investigation I found key violations will trigger an exception which makes it fairly simple to handle:

Code: perl

eval
{
$new_cust = Customer->insert({name=>"Rob", address=>"Rob's House", email=>"my\@email.com" }); # Insert using Class::DBI constructor.
}; &error($@) if $@; # Forward to error handler.

The eval block will catch the thrown exception, allowing you to gracefully handle it through your own subroutine.

Original post blogged on LessThanDot.

Writing Perl Tests with Test::More

Rob Earl — Sat, 15 Jan 2011 14:29:00 +0000

Writing tests for code is just as important as writing the code itself. Time spent writing tests is less time spent tracking down and fixing bugs, making it a great investment. Despite knowing this it can sometimes be hard to force yourself to stop coding and write tests. Fortunately, Perl has some modules to make it pretty simple. Here's the module we're going to be testing:

Code: perl

#!/usr/bin/perl

package MyMaths;
use strict;

sub new
{
my $proto = shift;
my $class = ref($proto) || $proto;
my $self = {};

bless($self, $class);
return $self;
}

sub add
{
my $self = shift;
my $total = 0;
foreach my $factor (@_)
{
$total += $factor;
}
return $total;
}

1;

As you can see, we have a simple class with one method, add, which adds together all the arguments passed to it. We now need to define a test file for this module, called mymaths.t:

Code: perl

#!/usr/bin/perl

use Test::More tests=>6;
use MyMaths;

$mymaths = new MyMaths;
is( $mymaths->add(1,2,3), 6, "1 + 2 + 3 = 6");
is( $mymaths->add(6,2), 8,"6 + 2 = 8");
is( $mymaths->add(1,2,3,4), 10, "1 + 2 + 3 + 4 = 10");
is( $mymaths->add(1,2), 3, "1 + 2 = 3");
is( $mymaths->add(2), 2, "2 = 2");
is( $mymaths->add(2,-1), 1, "2 + -1 = 1");

This test file uses the is() method of the builtin Test::More module. This method takes 3 arguments: the test, the expected result and a description. If a test fails, is() will give some feedback on the test.

edit: To run the tests use the `prove` utility which is part of the Test::Harness package:

prove -v mymaths.t

Run all tests in the current directory with:
prove -v .

~~To run the tests we use another builtin module, Test::Harness. Create tests.pl:~~

Code: perl

#!/usr/bin/perl

use Test::Harness qw(&runtests);

@tests = @ARGV ? @ARGV : <*.t>;

runtests @tests;

~~This script can either be run with a list of test files as arguments, or with no arguments to run all test files. Running the script results in:~~

Code: text

./mymaths.t ..
1..6
ok 1 - 1 + 2 + 3 = 6
ok 2 - 6 + 2 = 8
ok 3 - 1 + 2 + 3 + 4 = 10
ok 4 - 1 + 2 = 3
ok 5 - 2 = 2
ok 6 - 2 + -1 = 1
ok
All tests successful.
Files=1, Tests=6, 0 wallclock secs ( 0.01 usr 0.02 sys + 0.02 cusr 0.01 csys = 0.06 CPU)
Result: PASS

Everything went fine, as expected. Now go back to the original class definition and make a typo on line 22, so it reads = instead of += and rerun the tests:

Code: text

./mymaths.t ..
1..6
not ok 1 - 1 + 2 + 3 = 6
not ok 2 - 6 + 2 = 8
not ok 3 - 1 + 2 + 3 + 4 = 10
not ok 4 - 1 + 2 = 3
ok 5 - 2 = 2
not ok 6 - 2 + -1 = 1

# Failed test '1 + 2 + 3 = 6'
# at ./mymaths.t line 7.
# got: '3'
# expected: '6'

# Failed test '6 + 2 = 8'
# at ./mymaths.t line 8.
# got: '2'
# expected: '8'

# Failed test '1 + 2 + 3 + 4 = 10'
# at ./mymaths.t line 9.
# got: '4'
# expected: '10'

# Failed test '1 + 2 = 3'
# at ./mymaths.t line 10.
# got: '2'
# expected: '3'

# Failed test '2 + -1 = 1'
# at ./mymaths.t line 12.
# got: '-1'
# expected: '1'
# Looks like you failed 5 tests of 6.
Dubious, test returned 5 (wstat 1280, 0x500)
Failed 5/6 subtests

Test Summary Report
-------------------
./mymaths.t (Wstat: 1280 Tests: 6 Failed: 5)
Failed tests: 1-4, 6
Non-zero exit status: 5
Files=1, Tests=6, 0 wallclock secs ( 0.03 usr 0.00 sys + 0.03 cusr 0.00 csys = 0.06 CPU)
Result: FAIL

Most of the tests failed and gave good feedback to help find the problem.

Summary

Although writing tests can be a chore it is worth doing. If you write tests a little at a time:

When you design a class.
When you add a method to a class.
When you find a bug.

You'll develop a good library of tests without too much effort.

Calling Web Services from JSP

Rob Earl — Sat, 18 Dec 2010 14:40:51 +0000

This blog will demonstrate the steps to generate a Web Service Client and test JSP files in Eclipse. Finally, it will show a basic JSP example which uses the generated client to call a remote Web Service.

Setup Tomcat

Download and extract Tomcat 6.0. If you're using Ubuntu and want to use the system installed tomcat, follow these instructions.

Create an Eclipse Project

Open Eclipse and create a new Dynamic Web Project:

Give your project a name (JSPWSClient will do) and click "New" to add a New Server Runtime Environment. Select Apache Tomcat v6.0 and locate the directory you extracted to earlier.

Create Web Service Client

The client will use the Local Time Web Service from http://ripedevelopment.com/testService.aspx. Set the Service definition for the client to http://www.ripedevelopment.com/webservices/LocalTime.asmx?WSDL and drag the slider on the left to the top (Test Client).

If the server isn't already running the wizard will prompt you to "Start server", do this and, when prompted to generate a Web Service Client Test, accept the defaults to use Web Service Sample JSPs.

Eclipse will then generate a Web Service client and sample JSP files to test it. Once they are generated Eclipse will open the sample JSP client. Using this page the service methods can be tested to ensure connectivity with the service. Examining the source of these files in Project->WebContent->sampleLocalTimeSoapProxy can show us the methods we need to use.

Below is an example JSP file which will call the Web Service Client and lookup the current time in New York.

Code: java

<%@ page language="java" contentType="text/html; charset=UTF-8" pageEncoding="UTF-8"%>
<!DOCTYPE html PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN" "http://www.w3.org/TR/html4/loose.dtd">
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=UTF-8">
<title>The Time in New York!</title>
</head>
<body>
<jsp:useBean id="localTimeSoapProxy" scope="session" class="com.ripedev.www.LocalTimeSoapProxy" />
<%
try
{
String newYorkTime = localTimeSoapProxy.localTimeByZipCode("10001"); // Pass a New York zipcode.
%>The Time in New York is: <%=newYorkTime %>

<%
}
catch(Exception e)
{
%>
Exception: <%=e.getMessage() %>
<%
}
%>
</body>
</html>

Save this file to WebContent/NewYorkTime.jsp then navigate to http://localhost:8080/NewYorkTime.jsp and you should see something like:

The Time in New York is: 12/18/2010 11:26:22 AM

Original post blogged on LessThanDot.

Accurately Simulating Movement of a Tracked Vehicle in 2D Space

Rob Earl — Mon, 20 Sep 2010 16:41:38 +0000

As part of a simulation I've been developing I recently had to decide how to model movement of vehicles within a 2D space. To keep things simple I settled on a tracked vehicle. Each time the simulation updates I calculate how much the vehicle rotates and how far it moves based on the speed of it's tracks. From there I calculate the new coordinates for redrawing the vehicle.

Knowing the current location (x,y) and heading (h) I initially adopted a simplified way to calculate the rotation (g) and speed (s) based on the speed of the vehicle's tracks (T1 and T2) (Figure 1). With these variables I create a right angled triangle and use maths to calculate how far the vehicle moves in the x and y coordinates in order to find it's finishing location (x',y').

text

Web Developer - Author(s): Rob Earl

Adding Stackoverflow user feed to your homepage

Create HTML from output of Perl::Critic

Taming RSS Feeds with XML::RSS and Template::Toolkit

Get the Feed

Process the Raw Result

Format to Your Liking

Putting it All Together

Using a Perl Singleton to Share Values Between Objects

Catching Key Conflicts with Perl's Class::DBI

Writing Perl Tests with Test::More

Summary

Calling Web Services from JSP

Setup Tomcat

Create an Eclipse Project

Create Web Service Client

Accurately Simulating Movement of a Tracked Vehicle in 2D Space

Improving Accuracy

Rotation

Distance

Applying Our Findings

Example

How Much Difference Does It Really Make?

Automated Monitoring of Remote VNC Servers